mirror of
https://github.com/hsoft/collapseos.git
synced 2025-04-05 06:38:40 +11:00
9797405789
Totally reworked both parseDecimal and parseDecimalDigit parseDecimalDigit no longer exists, as it could be replaced by an inline alternative in the 4 places it appeared. This saves one byte overall, as the inline version is 4 bytes, 1 byte more than a call, and removing the function saved 5 bytes. It has been reduced from between 52 and 35 cycles (35 on error, so we'd expect 52 cycles to be more common unless someone's really bad at programming) to 14 cycles, so 2-3 times faster. parseDecimal has been reduced by a byte, and now the main loop is just about twice as fast, but with increased overhead. To put this into perspective, if we ignore error cases: For decimals of length 1 it'll be 1.20x faster, for decimals of length 2, 1.41x faster, for length 3, 1.51x faster, for length 4, 1.57x faster, and for length 5 and above, at least 1.48x faster (even faster if there's leading zeroes or not the worst case scenario). I believe there is still room for improvement, since the first iteration can be nearly replaced with "ld l, c" since 0*10=0, but when I tried this I could either add a zero check into the main loop, adding around 40 cycles and 10 bytes, or add 20 bytes to the overhead, and I don't think either of those options are worth it.
79 lines
1.7 KiB
NASM
79 lines
1.7 KiB
NASM
; *** Requirements ***
|
|
; None
|
|
;
|
|
; *** Code ***
|
|
|
|
; Parse the decimal char at A and extract it's 0-9 numerical value. Put the
|
|
; result in A.
|
|
;
|
|
; On success, the carry flag is reset. On error, it is set.
|
|
; Also, zero flag set if '0'
|
|
; parseDecimalDigit has been replaced with the following code inline:
|
|
; add a, 0xc6 ; Maps '0'-'9' onto 0xf6-0xff
|
|
; sub 0xf6 ; Anything but 0xf6-0xff carries
|
|
; Maps 0xf6-0xff onto 0-9
|
|
|
|
; Parse string at (HL) as a decimal value and return value in IX under the
|
|
; same conditions as parseLiteral.
|
|
; Sets Z on success, unset on error.
|
|
|
|
; 55 bytes, 32 cycles in first loop
|
|
; 90 cycles overhead + up to 69 cycles if length >= 5
|
|
; 140 cycles in loop
|
|
parseDecimal:
|
|
push hl
|
|
|
|
.skip: ; Skips leading zeroes
|
|
ld a, (hl)
|
|
inc hl
|
|
cp '0'
|
|
jr z, .skip
|
|
|
|
exx ; preserve bc, hl, de
|
|
ld hl, 0
|
|
ld b, 5 ; Carries can only occur for decimals >=5 in length
|
|
jr .start
|
|
|
|
.loop:
|
|
ld c, a ; c holds current digit
|
|
exx ;swap hl back in to get address
|
|
ld a, (hl) ; a checks if following digit is null at end of loop
|
|
inc hl
|
|
exx
|
|
add hl, hl ; x2
|
|
ld d, h
|
|
ld e, l ; de is x2
|
|
add hl, hl ; x4
|
|
add hl, hl ; x8
|
|
add hl, de ; x10
|
|
ld d, 0
|
|
ld e, c
|
|
add hl, de
|
|
jr c, .error ; if hl was 0x1999, it may carry here
|
|
; This check could be taken outside the loop, but at the cost of 6 bytes
|
|
|
|
.start:
|
|
add a, 0xc6 ; converts '0'-'9' to 0-9
|
|
sub 0xf6 ; carries if out of range
|
|
jr c, .error
|
|
|
|
djnz .loop
|
|
|
|
|
|
inc b ; so loop only executes once more
|
|
; only numbers >0x1999 can carry when multiplied by 10.
|
|
ld de, 0xE666
|
|
ex de, hl
|
|
add hl, de
|
|
ex de, hl
|
|
jr nc, .loop ; if it doesn't carry, it's small enough
|
|
.error:
|
|
sub 0xd0 ; if a is null, set Z
|
|
; a is checked for null before any errors
|
|
.end:
|
|
push hl
|
|
pop ix
|
|
exx ; restore original de and bc
|
|
pop hl
|
|
ret
|